project(Sketch3D)

find_package(Vulkan REQUIRED)

find_program(GLSLC glslc HINTS ${Vulkan_GLSLC_EXECUTABLE})
if(NOT GLSLC)
	set(GLSLC ${Vulkan_GLSLC_EXECUTABLE})
endif()

set(SHADER_GEN_DIR ${CMAKE_CURRENT_BINARY_DIR}/shaders_generated)
file(MAKE_DIRECTORY ${SHADER_GEN_DIR})

set(SHADER_INCS "")
foreach(SHADER stroke.vert stroke.geom stroke.frag)
	add_custom_command(
		OUTPUT ${SHADER_GEN_DIR}/${SHADER}.inc
		COMMAND ${GLSLC} -O --target-env=vulkan1.2 -mfmt=c
				${CMAKE_CURRENT_SOURCE_DIR}/shaders/${SHADER} -o ${SHADER_GEN_DIR}/${SHADER}.inc
		DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/shaders/${SHADER}
		COMMENT "Compiling ${SHADER} to SPIR-V"
		VERBATIM
	)
	list(APPEND SHADER_INCS ${SHADER_GEN_DIR}/${SHADER}.inc)
endforeach()
add_custom_target(Sketch3DShaders DEPENDS ${SHADER_INCS})

### ---------------------- Externals  ---------------------  ###
set(BINDINGS_INCLUDE)
set(BINDINGS_LIBS Imgui)

### ---------------------- Static Library  ---------------------  ###
file(GLOB SOURCES "./private/*.cpp" "./private/*/*.cpp")
file(GLOB HEADERS "./public/*.hpp" "./public/*/*.hpp")

add_library(${PROJECT_NAME} STATIC ${SOURCES} ${HEADERS})
add_dependencies(${PROJECT_NAME} Sketch3DShaders)

target_include_directories(${PROJECT_NAME} PUBLIC ./public/ ${BINDINGS_INCLUDE} ./ext/)
target_include_directories(${PROJECT_NAME} PRIVATE ./private/ ${SHADER_GEN_DIR})
target_link_libraries(${PROJECT_NAME} PUBLIC Graphics Connection WidgetsApp Math RasterRender Vulkan::Vulkan)
target_link_libraries(${PROJECT_NAME} PUBLIC ${BINDINGS_LIBS})

### -------------------------- Applications  --------------------------  ###
add_executable(Sketch3DApp ./applications/Entry.cpp)
target_link_libraries(Sketch3DApp ${PROJECT_NAME})

file(COPY "rsc" DESTINATION "${CMAKE_BINARY_DIR}/${PROJECT_NAME}/")
file(COPY "applications/Font.ttf" DESTINATION "${CMAKE_BINARY_DIR}/${PROJECT_NAME}/rsc")