Modules/Externals/CMakeLists.txt
Шурупов Илья Викторович 4b03ca04e3
Some checks failed
CI / applications (push) Failing after 3h0m11s
CI / linux (push) Has been skipped
CI / android (gallery, 1f71c52fcfd47062073560ad166ab65b27cfdbb790ebe77ee287dcae1e398d86, SKETCH2D) (push) Has been skipped
CI / android (sketch2d, 1f71c52fcfd47062073560ad166ab65b27cfdbb790ebe77ee287dcae1e398d86, SKETCH2D) (push) Has been skipped
CI / android (taskboard, 1f71c52fcfd47062073560ad166ab65b27cfdbb790ebe77ee287dcae1e398d86, SKETCH2D) (push) Has been skipped
Use pipe wakeups for Android curl resolver
The bundled curl resolver closes both ends of an eventfd wakeup pair even though they are the same descriptor. Android fdsan aborts when that descriptor number has been reused. Select curl’s pipe implementation on Android so the cleanup paths own distinct descriptors.
2026-11-18 10:16:50 +03:00

241 lines
10 KiB
CMake

find_package(Vulkan REQUIRED)
# GLFW serves the older Linux desktop tools; the apps use GraphicApplication's own backends.
if (CMAKE_SYSTEM_NAME STREQUAL "Linux")
add_subdirectory(glfw)
endif ()
project(Imgui)
set(${PROJECT_NAME}_SOURCES
imgui/imgui.cpp
imgui/imgui_draw.cpp
imgui/imgui_tables.cpp
imgui/imgui_widgets.cpp
imgui/imgui_demo.cpp
imgui/backends/imgui_impl_vulkan.cpp
implot/implot.cpp
implot/implot_items.cpp
imgui_config/ThreadLocalContext.cpp
)
if (CMAKE_SYSTEM_NAME STREQUAL "Linux")
list(APPEND ${PROJECT_NAME}_SOURCES
imgui/backends/imgui_impl_glfw.cpp
imgui/backends/imgui_impl_opengl3.cpp
)
endif ()
add_library(${PROJECT_NAME} STATIC ${${PROJECT_NAME}_SOURCES})
target_include_directories(${PROJECT_NAME} PUBLIC ./imgui/ ./imgui/backends/ ./implot/ ./imgui_config/)
target_compile_definitions(${PROJECT_NAME} PUBLIC IMGUI_USER_CONFIG="ThreadLocalContext.h")
target_link_libraries(${PROJECT_NAME} PUBLIC Vulkan::Vulkan)
if (CMAKE_SYSTEM_NAME STREQUAL "Linux")
target_link_libraries(${PROJECT_NAME} PRIVATE glfw)
endif ()
if (ANDROID)
add_library(native_app_glue STATIC ${ANDROID_NDK}/sources/android/native_app_glue/android_native_app_glue.c)
target_include_directories(native_app_glue PUBLIC ${ANDROID_NDK}/sources/android/native_app_glue)
target_link_libraries(native_app_glue PUBLIC android log)
endif ()
add_library(Picojson INTERFACE)
target_include_directories(Picojson INTERFACE ./picojson/)
project(Md4c)
add_library(${PROJECT_NAME} STATIC md4c/src/md4c.c)
target_include_directories(${PROJECT_NAME} PUBLIC ./md4c/src/)
set_target_properties(${PROJECT_NAME} PROPERTIES C_STANDARD 99 C_STANDARD_REQUIRED ON)
project(Nanovg)
add_library(${PROJECT_NAME} STATIC nanovg/src/nanovg.c)
target_include_directories(${PROJECT_NAME} PUBLIC ./nanovg/src/ ./nanovg/obsolete/)
project(NanovgVk)
add_library(${PROJECT_NAME} STATIC
nanovg_vulkan/src/nanovg.c
nanovg_vulkan/src/nanovg_vk.c
)
target_include_directories(${PROJECT_NAME} PUBLIC ./nanovg_vulkan/src/)
target_link_libraries(${PROJECT_NAME} PUBLIC Vulkan::Vulkan)
project(Lua)
add_library(${PROJECT_NAME} STATIC "lua/onelua.c")
target_compile_definitions(${PROJECT_NAME} PUBLIC MAKE_LIB)
target_include_directories(${PROJECT_NAME} PUBLIC "./lua")
set_target_properties(${PROJECT_NAME} PROPERTIES
C_STANDARD 99
C_STANDARD_REQUIRED ON
)
project(ImageIO)
add_library(${PROJECT_NAME} INTERFACE)
target_include_directories(${PROJECT_NAME} INTERFACE ./imageIO/)
set(UNITTEST_DIR ${CMAKE_CURRENT_SOURCE_DIR}/unittest-cpp)
file(GLOB UNITTEST_SOURCES ${UNITTEST_DIR}/UnitTest++/*.cpp)
if (WIN32)
file(GLOB UNITTEST_PLATFORM_SOURCES ${UNITTEST_DIR}/UnitTest++/Win32/*.cpp)
else ()
file(GLOB UNITTEST_PLATFORM_SOURCES ${UNITTEST_DIR}/UnitTest++/Posix/*.cpp)
endif ()
add_library(UnitTest++ STATIC ${UNITTEST_SOURCES} ${UNITTEST_PLATFORM_SOURCES})
target_include_directories(UnitTest++ PUBLIC ${UNITTEST_DIR})
add_subdirectory(googletest)
if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
if(CMAKE_BUILD_TYPE STREQUAL "Debug" AND NOT GHOSTTY_ZIG_BUILD_FLAGS)
set(GHOSTTY_ZIG_BUILD_FLAGS "-Doptimize=ReleaseSafe" CACHE STRING "Ghostty Zig build flags" FORCE)
endif()
add_subdirectory(ghostty)
endif()
if(ANDROID)
if(ANDROID_ABI STREQUAL "arm64-v8a")
set(GHOSTTY_ANDROID_TARGET aarch64-linux-android)
elseif(ANDROID_ABI STREQUAL "x86_64")
set(GHOSTTY_ANDROID_TARGET x86_64-linux-android)
else()
message(FATAL_ERROR "Ghostty VT does not support Android ABI ${ANDROID_ABI}")
endif()
find_program(GHOSTTY_ZIG_EXECUTABLE zig REQUIRED)
set(GHOSTTY_ANDROID_PREFIX "${CMAKE_CURRENT_BINARY_DIR}/ghostty-${ANDROID_ABI}")
set(GHOSTTY_ANDROID_ARCHIVE "${GHOSTTY_ANDROID_PREFIX}/lib/libghostty-vt.a")
add_custom_command(OUTPUT "${GHOSTTY_ANDROID_ARCHIVE}"
COMMAND "${GHOSTTY_ZIG_EXECUTABLE}" build -Demit-lib-vt -Dtarget=${GHOSTTY_ANDROID_TARGET}
-Doptimize=ReleaseFast --prefix "${GHOSTTY_ANDROID_PREFIX}"
WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/ghostty"
DEPENDS "${CMAKE_CURRENT_SOURCE_DIR}/ghostty/build.zig"
COMMENT "Building Ghostty VT for ${ANDROID_ABI}"
USES_TERMINAL)
add_custom_target(ghostty_android_vt DEPENDS "${GHOSTTY_ANDROID_ARCHIVE}")
add_library(ghostty-vt-static STATIC IMPORTED GLOBAL)
set_target_properties(ghostty-vt-static PROPERTIES
IMPORTED_LOCATION "${GHOSTTY_ANDROID_ARCHIVE}"
INTERFACE_INCLUDE_DIRECTORIES "${CMAKE_CURRENT_SOURCE_DIR}/ghostty/include"
INTERFACE_COMPILE_DEFINITIONS GHOSTTY_STATIC)
add_dependencies(ghostty-vt-static ghostty_android_vt)
endif()
# Windows cross-builds the same pinned Ghostty VT library with Zig for the GNU ABI that llvm-mingw links.
if(WIN32)
find_program(GHOSTTY_ZIG_EXECUTABLE zig REQUIRED)
set(GHOSTTY_WINDOWS_PREFIX "${CMAKE_CURRENT_BINARY_DIR}/ghostty-windows")
set(GHOSTTY_WINDOWS_ARCHIVE "${GHOSTTY_WINDOWS_PREFIX}/lib/ghostty-vt-static.lib")
add_custom_command(OUTPUT "${GHOSTTY_WINDOWS_ARCHIVE}"
COMMAND "${GHOSTTY_ZIG_EXECUTABLE}" build -Demit-lib-vt -Dtarget=x86_64-windows-gnu
-Doptimize=ReleaseFast --prefix "${GHOSTTY_WINDOWS_PREFIX}"
WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/ghostty"
DEPENDS "${CMAKE_CURRENT_SOURCE_DIR}/ghostty/build.zig"
COMMENT "Building Ghostty VT for Windows"
USES_TERMINAL)
add_custom_target(ghostty_windows_vt DEPENDS "${GHOSTTY_WINDOWS_ARCHIVE}")
add_library(ghostty-vt-static STATIC IMPORTED GLOBAL)
set_target_properties(ghostty-vt-static PROPERTIES
IMPORTED_LOCATION "${GHOSTTY_WINDOWS_ARCHIVE}"
INTERFACE_INCLUDE_DIRECTORIES "${CMAKE_CURRENT_SOURCE_DIR}/ghostty/include"
INTERFACE_COMPILE_DEFINITIONS GHOSTTY_STATIC
# Zig's standard library calls the native API directly.
INTERFACE_LINK_LIBRARIES ntdll)
add_dependencies(ghostty-vt-static ghostty_windows_vt)
endif()
# Taskboard's sync transport on Android and Windows: libcurl over mbedTLS (TLS 1.3) with nghttp2 (HTTP/2) and zstd,
# plus SQLite for the client cache. Linux desktop builds link the system libraries instead (see Taskboard/CMakeLists.txt).
# Expected sources: Externals/{curl,mbedtls,nghttp2,zstd,sqlite} (curl 8.11, mbedTLS 3.6, nghttp2 1.64, zstd 1.5.7,
# the SQLite amalgamation).
if (ANDROID OR WIN32)
foreach(entry curl/CMakeLists.txt mbedtls/CMakeLists.txt mbedtls/framework/CMakeLists.txt nghttp2/CMakeLists.txt
zstd/build/cmake/CMakeLists.txt sqlite/sqlite3.c)
if (NOT EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/${entry}")
message(FATAL_ERROR "Taskboard on ${CMAKE_SYSTEM_NAME} needs Externals/${entry}; run git submodule update --init --recursive")
endif ()
endforeach ()
set(ZSTD_BUILD_PROGRAMS OFF CACHE BOOL "" FORCE)
set(ZSTD_BUILD_SHARED OFF CACHE BOOL "" FORCE)
set(ZSTD_BUILD_TESTS OFF CACHE BOOL "" FORCE)
add_subdirectory(zstd/build/cmake EXCLUDE_FROM_ALL)
add_library(TaskboardZstd INTERFACE)
target_link_libraries(TaskboardZstd INTERFACE libzstd_static)
target_include_directories(TaskboardZstd INTERFACE ./zstd/lib)
set(ENABLE_PROGRAMS OFF CACHE BOOL "" FORCE)
set(ENABLE_TESTING OFF CACHE BOOL "" FORCE)
# Newer clang (llvm-mingw 23) warns about mbedTLS's deliberately unterminated label strings.
set(MBEDTLS_FATAL_WARNINGS OFF CACHE BOOL "" FORCE)
add_subdirectory(mbedtls EXCLUDE_FROM_ALL)
set(ENABLE_LIB_ONLY ON CACHE BOOL "" FORCE)
set(BUILD_STATIC_LIBS ON CACHE BOOL "" FORCE)
set(BUILD_SHARED_LIBS OFF CACHE BOOL "" FORCE)
add_subdirectory(nghttp2 EXCLUDE_FROM_ALL)
# curl's find modules accept these instead of searching the sysroot; the "libraries" are the targets above.
set(MBEDTLS_INCLUDE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/mbedtls/include" CACHE PATH "" FORCE)
set(MBEDTLS_LIBRARY mbedtls CACHE STRING "" FORCE)
set(MBEDX509_LIBRARY mbedx509 CACHE STRING "" FORCE)
set(MBEDCRYPTO_LIBRARY mbedcrypto CACHE STRING "" FORCE)
set(NGHTTP2_INCLUDE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/nghttp2/lib/includes;${CMAKE_CURRENT_BINARY_DIR}/nghttp2/lib/includes"
CACHE STRING "" FORCE)
set(NGHTTP2_LIBRARY nghttp2_static CACHE STRING "" FORCE)
set(ZSTD_INCLUDE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/zstd/lib" CACHE PATH "" FORCE)
set(ZSTD_LIBRARY libzstd_static CACHE STRING "" FORCE)
set(CURL_USE_MBEDTLS ON CACHE BOOL "" FORCE)
set(CURL_DISABLE_INSTALL ON CACHE BOOL "" FORCE)
# Host pkg-config must not leak desktop libraries (libidn2, brotli) into the cross build.
set(CURL_USE_PKGCONFIG OFF CACHE BOOL "" FORCE)
set(USE_LIBIDN2 OFF CACHE BOOL "" FORCE)
set(CURL_BROTLI OFF CACHE BOOL "" FORCE)
set(CURL_USE_GSSAPI OFF CACHE BOOL "" FORCE)
set(USE_LIBRTMP OFF CACHE BOOL "" FORCE)
set(CURL_ENABLE_EXPORT_TARGET OFF CACHE BOOL "" FORCE)
set(CURL_USE_OPENSSL OFF CACHE BOOL "" FORCE)
set(USE_NGHTTP2 ON CACHE BOOL "" FORCE)
set(CURL_ZSTD ON CACHE BOOL "" FORCE)
set(CURL_USE_LIBPSL OFF CACHE BOOL "" FORCE)
set(CURL_USE_LIBSSH2 OFF CACHE BOOL "" FORCE)
set(HTTP_ONLY ON CACHE BOOL "" FORCE)
set(BUILD_CURL_EXE OFF CACHE BOOL "" FORCE)
set(BUILD_TESTING OFF CACHE BOOL "" FORCE)
if (ANDROID)
set(HAVE_EVENTFD 0 CACHE INTERNAL "" FORCE)
endif ()
add_subdirectory(curl EXCLUDE_FROM_ALL)
target_compile_definitions(libcurl_static PRIVATE NGHTTP2_STATICLIB)
add_library(TaskboardCurl INTERFACE)
target_link_libraries(TaskboardCurl INTERFACE CURL::libcurl_static)
add_library(TaskboardSqlite STATIC sqlite/sqlite3.c)
target_include_directories(TaskboardSqlite PUBLIC ./sqlite)
target_compile_definitions(TaskboardSqlite PRIVATE SQLITE_THREADSAFE=1 SQLITE_OMIT_LOAD_EXTENSION)
endif ()
function(modules_add_lottie)
set(CMAKE_POLICY_VERSION_MINIMUM 3.5)
set(BUILD_SHARED_LIBS OFF)
set(LOTTIE_MODULE OFF CACHE BOOL "" FORCE)
set(LOTTIE_THREAD OFF CACHE BOOL "" FORCE)
set(LOTTIE_TEST OFF CACHE BOOL "" FORCE)
add_subdirectory(rlottie EXCLUDE_FROM_ALL)
target_include_directories(rlottie PUBLIC "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/rlottie/inc>")
target_compile_options(rlottie PRIVATE -Wno-error "$<$<COMPILE_LANGUAGE:CXX>:-include>" "$<$<COMPILE_LANGUAGE:CXX>:limits>")
if (WIN32)
# Static on Windows: LOT_BUILD keeps the headers from declaring the API dllimport, in rlottie and its users.
target_compile_definitions(rlottie PUBLIC LOT_BUILD)
# libc++ on mingw does not pull these in transitively the way libstdc++ does.
foreach(header functional iterator memory)
target_compile_options(rlottie PRIVATE "$<$<COMPILE_LANGUAGE:CXX>:SHELL:-include ${header}>")
endforeach()
endif ()
endfunction()
modules_add_lottie()
include(Voice.cmake)
include(Video.cmake)
include(Yuv.cmake)