mirror of
https://github.com/blender/blender
synced 2026-10-25 03:07:01 +03:00
d5d927b670
### New libraries - meshoptimizer v1.0 - tomli-w 1.2.0 - Tracy 0.13.1 ### Updates of existing libraries - OpenShadingLanguage 1.15.3.0 - OpenPGL 0.7.1 - ThorVG 1.0.3 - OpenUSD 26.03 - OpenImageIO 3.1.13.1 - libpng 1.6.58 - DPC++ 6.3.0 - Embree 4.4.1 - Intel Graphics Compiler v2.30.1 - Manifold 3.4.1 - x265 4.1 - ROCm / HIP 7.1.1 / 7.1.51803 - libexpat 2.7.5 - libtiff 4.7.1 - mesa 25.3.6 - OpenEXR 3.4.10 - OpenSSL 3.5.6 - Python 3.13.13 - sqlite 3.51.3 - libxml2 2.14.6 - ffmpeg 8.1 - Draco 1.5.7 - SDL 3.4.2 Library changes tracking issue ref: #153974 Co-authored-by: Sebastian Parborg <sebastian@blender.org> Co-authored-by: Ray Molenkamp <github@lazydodo.com> Co-authored-by: Sahar A. Kashi <salipour@noreply.localhost> Co-authored-by: Nikita Sirgienko <nikita.sirgienko@intel.com> Co-authored-by: Bart van der Braak <bart@blender.org> Co-authored-by: Thomas Dinges <thomas@blender.org> Co-authored-by: Alaska <Alaskayou01@gmail.com> Pull Request: https://projects.blender.org/blender/blender/pulls/157180
81 lines
2.4 KiB
CMake
81 lines
2.4 KiB
CMake
# # SPDX-FileCopyrightText: 2025 Blender Authors
|
|
# #
|
|
# # SPDX-License-Identifier: GPL-2.0-or-later
|
|
|
|
if(WIN32)
|
|
set(RUBBERBAND_CONFIGURE_ENV ${CONFIGURE_ENV_MSVC})
|
|
set(FFTW_DIR ${LIBDIR}/fftw3/lib/pkgconfig)
|
|
file(TO_NATIVE_PATH "${FFTW_DIR}" FFTW_DIR)
|
|
set(RUBBERBAND_PKG_ENV PKG_CONFIG_PATH=${FFTW_DIR})
|
|
else()
|
|
set(RUBBERBAND_CONFIGURE_ENV ${CONFIGURE_ENV})
|
|
set(RUBBERBAND_PKG_ENV "PKG_CONFIG_PATH=\
|
|
${LIBDIR}/fftw3/lib/pkgconfig:\
|
|
$PKG_CONFIG_PATH"
|
|
)
|
|
endif()
|
|
|
|
set(RUBBERBAND_EXTRA_OPTIONS
|
|
-Dauto_features=disabled
|
|
-Ddefault_library=static
|
|
-Dfft=fftw
|
|
)
|
|
|
|
ExternalProject_Add(external_rubberband
|
|
URL file://${PACKAGE_DIR}/${RUBBERBAND_FILE}
|
|
DOWNLOAD_DIR ${DOWNLOAD_DIR}
|
|
URL_HASH ${RUBBERBAND_HASH_TYPE}=${RUBBERBAND_HASH}
|
|
PREFIX ${BUILD_DIR}/rubberband
|
|
|
|
PATCH_COMMAND
|
|
${PATCH_CMD} -p 1
|
|
-d ${BUILD_DIR}/rubberband/src/external_rubberband
|
|
-i ${PATCH_DIR}/rubberband_remove_dll_exports.diff &&
|
|
${PATCH_CMD} -p 1
|
|
-d ${BUILD_DIR}/rubberband/src/external_rubberband
|
|
-i ${PATCH_DIR}/rubberband_missing_cstdlib.diff
|
|
|
|
CONFIGURE_COMMAND ${RUBBERBAND_CONFIGURE_ENV} &&
|
|
${CMAKE_COMMAND} -E env ${RUBBERBAND_PKG_ENV} ${MESON} setup
|
|
--prefix ${LIBDIR}/rubberband
|
|
--libdir lib
|
|
${MESON_BUILD_TYPE}
|
|
${RUBBERBAND_EXTRA_OPTIONS}
|
|
${BUILD_DIR}/rubberband/src/external_rubberband-build
|
|
${BUILD_DIR}/rubberband/src/external_rubberband
|
|
|
|
BUILD_COMMAND ninja
|
|
INSTALL_COMMAND ninja install
|
|
INSTALL_DIR ${LIBDIR}/rubberband
|
|
)
|
|
|
|
add_dependencies(
|
|
external_rubberband
|
|
external_fftw
|
|
# Needed for `MESON`.
|
|
external_python_site_packages
|
|
)
|
|
|
|
if(WIN32)
|
|
if(BUILD_MODE STREQUAL Release)
|
|
ExternalProject_Add_Step(external_rubberband after_install
|
|
COMMAND ${CMAKE_COMMAND} -E copy_directory
|
|
${LIBDIR}/rubberband/include
|
|
${HARVEST_TARGET}/rubberband/include
|
|
COMMAND ${CMAKE_COMMAND} -E copy
|
|
${LIBDIR}/rubberband/lib/rubberband-static.lib
|
|
${HARVEST_TARGET}/rubberband/lib/rubberband-static.lib
|
|
DEPENDEES install
|
|
)
|
|
else()
|
|
ExternalProject_Add_Step(external_rubberband after_install
|
|
COMMAND ${CMAKE_COMMAND} -E copy
|
|
${LIBDIR}/rubberband/lib/rubberband-static.lib
|
|
${HARVEST_TARGET}/rubberband/lib/rubberband-static_d.lib
|
|
DEPENDEES install
|
|
)
|
|
endif()
|
|
else()
|
|
harvest(external_rubberband rubberband/include rubberband/include "*.h")
|
|
harvest(external_rubberband rubberband/lib rubberband/lib "*.a")
|
|
endif()
|